LET in Excel: So verwendest du es
Mit LET gibst du einem Zwischenergebnis in deiner Formel einen Namen. Excel rechnet es nur einmal aus, und eine lange Formel wird leichter lesbar. Funktioniert in Excel 2021 und 365.
Probier die ersten Übungen kostenlos ausIn der Lektion Excel 365 für Fortgeschrittene
Was macht LET?
Mit LET gibst du einem Zwischenergebnis in deiner Formel einen Namen. Excel rechnet es einmal aus, und du verwendest den Namen so oft, wie du willst. Eine lange Formel wird so kürzer und leichter lesbar.
Du gibst jedes Mal einen Namen und einen Wert an, und zum Schluss die Berechnung, die diese Namen verwendet. Ein Name darf auch einen früheren Namen verwenden. Der Name gilt nur in dieser einen Formel. LET funktioniert in Excel 2021 und 365.
Wann verwendest du LET?
- Ein Rabatt, wenn der Gesamtbetrag über einer Grenze liegt, ohne A2*B2 dreimal zu tippen: =LET(gesamt;A2*B2;WENN(gesamt>100;gesamt*0,9;gesamt)).
- Die Abweichung vom Mittelwert in Prozent: =LET(mittel;MITTELWERT(B2:B50);(B2-mittel)/mittel).
- Ein Betrag mit Mehrwertsteuer, mit benannten Schritten: =LET(gesamt;A2*B2;mwst;gesamt*19%;gesamt+mwst).
- Eine Formel lesbarer machen, die dasselbe Nachschlagen mehrmals braucht.
Syntax
Die Syntax ist das feste Muster einer Funktion. Die Wörter zwischen den Klammern sind Platzhalter: Dort setzt du selbst etwas ein, zum Beispiel eine Zelle, eine Zahl oder einen Text. Alles andere tippst du genau so, wie es dasteht.
Mit einem Beispiel: =LET(gesamt;A2*B2;WENN(gesamt>100;gesamt*0,9;gesamt))
So liest du die Formel, Teil für Teil:
| Teil | Was es bedeutet | Im Beispiel |
|---|---|---|
= | Jede Formel beginnt mit einem Gleichheitszeichen. Ohne = hält Excel, was du tippst, für gewöhnlichen Text. | = |
LET | Der Name der Funktion: So weiß Excel, was es tun soll. Du darfst ihn kleinschreiben, Excel setzt ihn selbst in Großbuchstaben. | LET |
( ) | Direkt nach dem Namen kommen die Klammern. Dazwischen steht, was die Funktion zum Arbeiten braucht: die Argumente. | ( ) |
Name | Der Name des Zwischenergebnisses, etwa gesamt. Er darf nicht wie eine Zelladresse aussehen. | gesamt |
Wert | Wofür der Name steht, etwa A2*B2. | A2*B2 |
Berechnung | Die Berechnung, die den Namen verwendet. Ihr Ergebnis siehst du in der Zelle. | WENN(gesamt>100;gesamt*0,9;gesamt) |
; | Ein Semikolon trennt die Argumente voneinander. In einem englischen Excel ist das ein Komma. | ; |
LET Schritt für Schritt
C2 enthält =LET(gesamt;A2*B2;WENN(gesamt>100;gesamt*0,9;gesamt)). 12,50 × 10 ist 125, mehr als 100: Mit 10 % Rabatt zahlst du 112,50. Ändere die Zahlen oder die Formel und schau, was passiert.
So baust du die Formel selbst auf:
- Klick auf C2 und tippe LET mit einer Klammer.
=LET( - Tippe den Namen des Zwischenergebnisses, gesamt, und ein Semikolon.
=LET(gesamt; - Tippe, wofür der Name steht: A2*B2, und ein Semikolon.
=LET(gesamt;A2*B2; - Tippe die Berechnung mit dem Namen: ein WENN, das gesamt mit 100 vergleicht und sonst 10 % Rabatt gibt.
=LET(gesamt;A2*B2;WENN(gesamt>100;gesamt*0,9;gesamt) - Schließ die letzte Klammer und drück die Eingabetaste: 112,50.
=LET(gesamt;A2*B2;WENN(gesamt>100;gesamt*0,9;gesamt))
Weitere Beispiele
Zwei Namen
C2 enthält =LET(preis;A2;menge;B2;preis*menge). Jeder Name bekommt seinen eigenen Wert: preis und menge. Die Berechnung am Ende verwendet beide: 125.
Die Abweichung vom Mittelwert
D2 enthält =LET(mittel;MITTELWERT(B2:B4);(B2-mittel)/mittel). Der Mittelwert ist 14. Leas 16 liegt 2 darüber, und 2 geteilt durch 14 sind 14 %.
Ein Name, der einen früheren Namen verwendet
C2 enthält =LET(gesamt;A2*B2;mwst;gesamt*19%;gesamt+mwst). mwst verwendet gesamt: 19 % von 125 sind 23,75, also 148,75 zusammen.
Wo es oft schiefgeht
- Ein Name darf nicht wie eine Zelladresse aussehen: x oder gesamt geht, A1 oder UST1 nicht.
- Der Name gilt nur in dieser einen Formel. In einer anderen Zelle kennt Excel ihn nicht: Dort bekommst du #NAME?.
Übe das in der Lektion Excel 365 für Fortgeschrittene. Die ersten Übungen sind kostenlos.
Häufige Fragen
Was ist der Unterschied zu einem benannten Bereich?
Ein benannter Bereich gilt in der ganzen Arbeitsmappe und verweist auf Zellen. Ein Name in LET gilt nur in dieser einen Formel und kann jede beliebige Berechnung enthalten.